CARA MEMATIKAN UPDATE WINDOWS 10

Sedang mengalami masalah dengan windows update?

Sebagai buruh harian lepas dan penjaga perawatan komputer, awalnya saya selalu mengikuti update windows. Tapi karena dari bulan 10 kemarin saya mengalami error dalam sharing komputer dalam jaringan lokal saya, akhirnya saya memutuskan untuk menonaktifkan update windows.

Untuk cara disable sebenarnya banyak, misalnya dengan mendownload program untuk disable update windows 10. Tetapi sering kali link hasil kita browsing malah membawa kita ke situs yang berisi virus.

Untuk saya pilihan yang saya sukai adalah dengan melakukan perubahan pada registry windows. Jika anda tidak memahami registry windows maka cukup download script yang sudah saya sediakan di link dibawah ini. Klik kanan lalu pilih run as administrator.

 DOWNLOAD 

Jika anda ragu dengan script saya, maka akan saya jabarkan seperti dibawah ini.

@echo off

title https://ndalu.id - Disable/Enable Windows 10 Automatic Updates
color 8
:Begin UAC check and Auto-Elevate Permissions
:-------------------------------------
REM  --> Check for permissions
>nul 2>&1 "%SYSTEMROOT%\system32\cacls.exe" "%SYSTEMROOT%\system32\config\system"

REM --> If error flag set, we do not have admin.
if '%errorlevel%' NEQ '0' (
	echo:
		echo   Requesting Administrative Privileges...
		echo   Press YES in UAC Prompt to Continue
	echo:
		goto UACPrompt
) else (
	goto gotAdmin
)

:UACPrompt
    echo Set UAC = CreateObject^("Shell.Application"^) > "%temp%\getadmin.vbs"
    echo UAC.ShellExecute "%~s0", "", "", "runas", 1 >> "%temp%\getadmin.vbs"
    "%temp%\getadmin.vbs"
    exit /B

:gotAdmin
    if exist "%temp%\getadmin.vbs" ( del "%temp%\getadmin.vbs" )
    pushd "%CD%"
    CD /D "%~dp0"
:--------------------------------------

:Check Windows Version
wmic os get version | find /i "10.">nul 2>nul
if %errorlevel% neq 0 GOTO :Not10

:Check the key:
(reg query "HKEY_LOCAL_MACHINE\SOFTWARE\Policies\Microsoft\Windows\WindowsUpdate\AU" /v "NoAutoUpdate"|find /i "0x1")>NUL 2>NUL
if %errorlevel% neq 0 GOTO :KEYOFF

:KEYON
echo ============================================================
echo https://ndalu.id
echo Windows update is INACTIVE/DISABLE
echo Disable windows update? Type: Y/N
echo ============================================================
echo.
choice /c yn /n
If %ERRORLEVEL% NEQ 1 GOTO :QUIT

echo Closing windows update
net stop wuauserv>NUL 2>NUL
echo.

Echo Changing Registry key
REG ADD "HKEY_LOCAL_MACHINE\SOFTWARE\Policies\Microsoft\Windows\WindowsUpdate\AU" /v "NoAutoUpdate" /D 0 /T REG_DWORD /F>NUL 2>NUL
IF %ERRORLEVEL% NEQ 0 GOTO :ERROR
Echo.

Echo Windows update is ENABLED successfully
Echo.
goto :QUIT


:KEYOFF
echo ============================================================
echo https://ndalu.id
echo Windows update is ACTIVE/ENABLE
echo Disable windows update? Type: Y/N
echo ============================================================
echo.
choice /c yn /n
If %ERRORLEVEL% NEQ 1 GOTO :QUIT

echo Closing windows update
net stop wuauserv>NUL 2>NUL
echo.

Echo Changing Registry key
REG ADD "HKEY_LOCAL_MACHINE\SOFTWARE\Policies\Microsoft\Windows\WindowsUpdate\AU" /v "NoAutoUpdate" /D 1 /T REG_DWORD /F>NUL 2>NUL
IF %ERRORLEVEL% NEQ 0 GOTO :ERROR
Echo.

Echo Windows update is DISABLED successfully
Echo.
goto :QUIT


:QUIT
echo ============================================================
echo Press ay key to close this window
echo ============================================================
pause>NUL
goto :EOF

:ERROR
echo ============================================================
echo The script ran into an unexpected error setting reg key.
echo Press ay key to close this window
echo ============================================================
pause>NUL
goto :EOF

:Not10
echo ============================================================
echo Windows 10 script only
echo Press ay key to close this window
echo ============================================================
pause>NUL
goto :EOF

Jadi jangan ragu, untuk download dan jalankan scriptnya.


ARTIKEL TERKAIT
Comments : To post comment, you must login first using google. No worry, it's safe